初遇 IoT ( Internet of Thing, 物聯網 ) - 使用 Arduino 控制 ESP8266 無線模組上傳資料到 IoT Server ( ThingSpeak )

網頁最後修改時間：2017/01/07

ThingSpeak 環境溫濕度記錄圖

網路是構成物聯網 ( IoT, Internet of Things ) 其中一項不可或缺的技術，而 IoT Server 就是用來蒐集並記錄由世界各地傳過來的數據資料，這些資料可以自己使用也可以分享給其他人做使用，這對於需要在世界各地蒐集資料的科學家或是程式設計師，善用這些資料可以加速其研究分析的工作，節省很多的時間。例如，對於科技農夫來說，可以蒐集整片土地上面各處土壤的溫溼度、光照程度在特定時間間隔的分佈狀態，以長時間的數據來分析影響土地上各植物的生長狀態的因素，幫助農夫可以做製程改善達到最大的產量輸出。當然，還有很多的應用，可以利用物聯網的方式來實現，而本篇網頁提出一個實際的例子來說明，如何使用賣場的 "ESP8266 IoT 入門學習套件" 每隔 60 秒傳送環境溫濕度到 IoT Server ( ThingSpeak ) 做紀錄。

*********************************************************************************
   物聯網，維基百科的解釋
*********************************************************************************
*********************************************************************************
此網頁所用的材料可自行準備，或選用新版本的升級套件

• V2.1 版 { 萬物皆聯網-ESP8266 IoT(Internet of Things)入門學習套件 }

更多 ESP8266 相關商品，請至分類賣場
*********************************************************************************

我所使用的 IoT Server 是由 ThingSpeak 所提供，支援很多微處理器和控制器，也提供相對應的使用範例做為使用上的參考，上手很快也很方便。重點是：ThingSpeak 是開源的，可以下載並安裝在自己的電腦上做 IoT Server。

*********************************************************************************

Internet of Things - ThingSpeak

ThingSpeak 開放原始碼 - GitHub

ThingSpeak is an open source “Internet of Things” application and API to store and retrieve data from things using HTTP over the Internet or via a Local Area Network. With ThingSpeak, you can create sensor logging applications, location tracking applications, and a social network of things with status updates.

ThingSpeak 教學 - Tutorials

參考網頁：

• ThingSpeak - Using an Arduino + Ethernet Shield to Update a ThingSpeak Channel
• Instructable - ESP8266 Wifi Temperature Logger
  網頁主要是參考這篇文章裡的內容，作者給了很大的幫助！但是實際上，照著做並不能成功上傳資料，原因在於：(1) 作者的 ESP8266 韌體有可能是舊版的，或是已事先輸入幾個設定的 AT 指令進入模組，因為沒有出現在程式碼中，直接使用程式碼是無法正常上傳資料的；(2) 作者使用 3V3 的 Arduino 板子和 DS18B20 溫度感測器，線路是不一樣的，程式碼必須重新修改；(3) 作者使用單筆資料而非多筆資料同時上傳，這部分需要上 ThingSpeak 網站上面找一下資料。

*********************************************************************************

下面分為幾個步驟來實現溫溼度上傳到 IoT Server - ThingSpeak 的目的：

• 申請一個 ThingSpeak 帳號
  .
• 建立一個給 DHT11 使用的 Channel
  .
• 取得剛剛建立的 ThingSpeak Channel 的( Write ) API KEY，並手動測試
  .
• HTTP 方法：POST 和 GET
  .
• 佈線電路圖說明
  .
• 程式測試說明

Note：所有這網頁需要的資料全部都已經上傳到賣場雲端硬碟中，請至目錄中下載或是直接移至自己的雲端硬碟。
電路圖：ESP8266 IoT 入門學習套件 / schematics / Arduino_IoT_Demo
程式碼：ESP8266 IoT 入門學習套件 / codes / Arduino / IoT_demo


申請一個 ThingSpeak 帳號：

ThingSpeak 帳號申請很簡單，直接進入 ThingSpeak.com 主網頁點擊右上角的 Sign Up 連結進入註冊頁面。進入頁面後，依照欄位輸入相對應的資料，如下圖所示。

ThingSpeak 新帳號申請頁面

建立一個給 DHT11 使用的 Channel：

完成帳號申請之後，按下 Create Account 按鈕就會跳轉到下面的頁面，這時已經確認產生新的帳號，可以開始設定 Channel

ThingSpeak - My Channels 頁面

Channel Settings 的頁面中，要設定的只有三個地方

• Name ：Channel 的名稱，這裡請設定為 DHT11
• Field 1：資料欄位的顯示名稱，請設定為 Temperature ( degC )
• Filed 2：資料欄位的顯示名稱，請設定為 Humidity ( % )

ThingSpeak Channel Settings - 欄位名稱設定

這些設定的文字只是為了辨識輸入的資料欄位是代表什麼，實際從遠端輸入資料到 ThingSpeak IoT Server 時，資料欄位的輸入都是有固定的格式，程式設計師要知道的最重要的東西是這個 Channel 的 Write API Key 和 Read API Key，從遠端輸入資料時，就是傳送這個 API Key 給 ThingSpeak IoT Server，Server 才會知道這資料是屬於哪一個使用者的哪一個 Channel 的欄位資料；每一個 ThingSpeak 的 Channel 最多有 8 個 資料欄位。

輸入完畢後按下最下方的 Save Channel 按鈕儲存資料；另外，Clear Channel 按鈕是用來清除所有以記錄的資料，這等一下會用到，要記得清除資料是在這裡清除！


取得剛剛建立的 ThingSpeak Channel 的( Write ) API KEY，並手動測試：

在同樣的頁面，上方有一顆 API Keys 按鈕，按進去就會出現剛剛這個 Channel 的寫入的 API Key，將 Write API Key 先複製或是記下來，等一下測試會用到！

ThingSpeak - Channel's API Key

假設我們取得剛剛產生的 Channel 的 Write API Key 是 ALSKUJG6DR5PLODE，要設定的溫濕度分別是 25 度 C 與 75 %，那輸入的標準格式是

http://api.thingspeak.com/update?key=[THINGSPEAK_KEY]&field1=[溫度]&field2=[濕度]

根據我們所設定的溫度，則完整的輸入就會變成

http://api.thingspeak.com/update?key=ALSKUJG6DR5PLODE&field1=25&field2=75

打開瀏覽器，複製上面的資料 ( 記得換上自己的 Write API Key )，按下 Enter，若成功傳入資料到剛剛在 ThingSpeak 新增的 Channel，那麼就會在瀏覽器視窗收到 1

傳送測試的溫溼度資料到 ThingSpeak

到底資料傳進去了沒有，我們來確認一下！

同樣在 Channels 頁面下，按下 Private View 就會看到兩個趨勢圖 ( 方便顯示起見，我將下方的圖移到右邊 )，而顯示的結果與我們剛剛輸入的資料相同，這也就表示上面的輸入格式與資料都是正確的。

檢視測試輸入資料的結果

使用上面剛剛建立的資料輸入方式，只要更改 field1= 與 field2= 後面的數值，就可以將資料上傳到 ThingSpeak 所建立的 Channel 相對應的資料欄位中，容易吧！

這段建立的資料格式將會使用到 Arduino 程式碼中，負責將整段格式移交給 ESP8266 無線模組來處理。但是瀏覽器傳送時是使用 HTTP 的方法傳送，類似於我們在網頁輸入表單資料後，需要按下表單按鈕以傳送資料到伺服器去，伺服器再根據資料回傳給我們，所以並不是直接輸入上面的格式就可以。這就是我們下一段要討論的 HTTP Method：GET 和 POST 方法。


HTTP 方法：POST 和 GET

ThingSpeak 提供了使用 Arduino 配合有線網路模組的例子，傳送的 HTTP 方法是 POST，與上面所做測試的方法是不一樣的。因為使用 POST 是看不到傳送的欄位資料出現在瀏覽器的網址列中，所以在上面傳送資料的 HTTP 方法是使用 GET。

這兩種 HTTP 方法主要的不同在於，

GET：查詢字串 ( name / value pairs，名稱  / 值對 ) 是在 GET 請求的 URL 中發送的

• 請求數據長度有限制

POST：查詢字串 ( name / value pairs，名稱 / 值對 ) 是在 POST 請求的消息主體中發送的

• 請求數據長度沒有要求

上面只簡單列出跟網頁相關最重要的，其他的可參考 "淺談 HTTP Method：表單中的 GET 與 POST 有什麼差別？" 這篇網頁中的說明。

ThingSpeak 裡面所使用的例子是使用 POST 發送數據，會換成使用 GET 的方式是因為他的傳送格式簡單，只要一行就可以搞定；若是利用 POST 要傳送一堆標頭才能傳送本體 ( 資料放在此 )，有點浪費時間！尤其是在微處理機使用上，盡量簡單就好。等到那一天發現到這方法不適用時，再換成 POST 方式就好。


佈線電路圖說明：

IoT_Demo 電路圖 V0.2 - 包括 UART 除錯

測試時，Arduino 是直接插在筆電，與筆電通訊和供電，所有外部模組和零件所用到的，不管是 3V3 或是 5V電源都是來自 Arduino。雖然我這樣測試是正常的，但不代表其他人就會一樣！若出現問題，請先確認 ESP8266 無線模組所供應的電源是否在範圍內；簡單一點的方法就是換成套件中的電源模組做 ESP8266 的 3V3 電源，這會解決大部分因為電源不穩定所引起的問題。

上面的電路圖中，USB 轉 TTL 模組是用來做除錯用的。程式執行的過程中會送出除錯的訊息，依但程式出現問題時才抓的到；硬體 UART 用來與 ESP8266 直接通訊用，程式寫起來會輕鬆許多。

所需材料：

• 1  x  pcs  [ Arduino 板子 ]
• 1  x  pcs  [ ESP8266, ESP-01 無線模組 ]
• 1  x  pcs  [ USB 轉 TTL 模組 ]
• 1  x  pcs  [ DHT11 ( 溫溼度感測器 ) ]
• 1  x  pcs  [ Level Shifter ( 3V3 / 5V 電壓準位轉換模組 ) ]
• 1  x  pcs  [ 4.7 K 電阻 ]
• 1  x  pcs  [ 麵包板 ]，哪一種形式都可以，能用就好！
• 杜邦線 ( 母對母，公對公 )

*********************************************************************************
如果需要中間那個電壓轉換模組，可以依照 "使用 N-Channel MOSFET 做 I2C 電壓準位轉換電路" 網頁中的說明自己佈線，或是到下面連結購買

• 四通道雙向邏輯電壓準位(適用1.8V,2.8V,3.3V,5.0V )轉換模組(支援 I2C, SPI, 一般邏輯準位)

*********************************************************************************

實際接線圖

程式測試說明：
*********************************************************************************
2016/12/20 更新：
由於使用的感測器並不一定會與網頁上使用的 ( DHT11 ) 相同，因此並未將所使用的 DHT11 函式庫連結附上，主要是考量到這只是 ESP8266 的應用，但因為常有私信問我要，所以檔案連結在下面，不需要再寫信跟我要了！

DHT11 Arduino Library (最新版)

若上面最新版本使用有問題，可改用下面舊版本函式庫使用
DHT11 Arduino Library (網頁程式使用的舊版本 DHT11 函式庫)

直接複製到 "文件/{Arduino IDE}/libraries " 目錄下，重新開啟 Arduino IDE 即可！
*********************************************************************************

接好線路之後 ( USB 轉 TTL 模組的線路可以不接，除非想要看到實際的輸出情形，或是需要除錯 )，完整的程式碼列在下面 ( 雲端硬碟裡面的程式碼裡面有特別做註解 )，將其複製到 Arduino IDE 中。

Note：請注意使用的 ESP8266 板子的通訊速率是使用多少 ? 若是購買賣場藍色板子，就不需要修改下面的程式碼可以直接使用；但若是使用黑色板子，下面的 #define _baudrate 要改成 115200

#include <SoftwareSerial.h>
#include "DHT.h"

#define DEBUG

#define _ledpin     13

//*-- Hardware Serial
#define _baudrate   9600

//*-- Software Serial
// 
#define _rxpin      2
#define _txpin      3
SoftwareSerial debug( _rxpin, _txpin ); // RX, TX

//*-- DHT11
#define _dhtpin     8
#define _dhttype    DHT11

DHT dht11( _dhtpin, _dhttype );
uint8_t dhtbuf[2];

//*-- IoT Information
#define SSID "[無線網路熱點名稱]"
#define PASS "[無線網路連線密碼]"
#define IP "184.106.153.149" // ThingSpeak IP Address: 184.106.153.149
// 使用 GET 傳送資料的格式
// GET /update?key=[THINGSPEAK_KEY]&field1=[data 1]&filed2=[data 2]...;
String GET = "GET /update?key=[ThingSpeak_(Write)API_KEY]";

void setup() {
    Serial.begin( _baudrate );
    debug.begin( _baudrate );

    sendDebug("AT");
    delay(5000);
    if(Serial.find("OK"))
    {
        debug.println("RECEIVED: OK\nData ready to sent!");
        connectWiFi();
    }

    // DHT11
    dht11.begin();

    pinMode( _ledpin, OUTPUT );
    digitalWrite( _ledpin, LOW );
}

void loop() {
    dhtbuf[0] = dht11.readHumidity();
    dhtbuf[1] = dht11.readTemperature();

    // 確認取回的溫溼度數據可用
    if( isnan(dhtbuf[0]) || isnan(dhtbuf[1]) )
    {
        debug.println( "Failed to read form DHT11" );
    }
    else
    {
        digitalWrite( _ledpin, HIGH );
        char buf[3];
        String HH, TT;
        buf[0] = 0x30 + dhtbuf[1] / 10;
        buf[1] = 0x30 + dhtbuf[1] % 10;
        TT = (String(buf)).substring( 0, 2 );
        buf[0] = 0x30 + dhtbuf[0] / 10;
        buf[1] = 0x30 + dhtbuf[0] % 10;
        HH = (String(buf)).substring( 0, 2 );

        updateDHT11( TT, HH );
        #ifdef DEBUG
            debug.print("Humidity: "); 
            debug.print( HH );
            debug.print(" %\t");
            debug.print("Temperature: "); 
            debug.print( TT );
            debug.println(" *C\t");
        #endif
        digitalWrite( _ledpin, LOW );
    }

    delay(60000);   // 60 second
}

void updateDHT11( String T, String H )
{
    // 設定 ESP8266 作為 Client 端
    String cmd = "AT+CIPSTART=\"TCP\",\"";
    cmd += IP;
    cmd += "\",80";
    sendDebug(cmd);
    delay(2000);
    if( Serial.find( "Error" ) )
    {
        debug.print( "RECEIVED: Error\nExit1" );
        return;
    }

    cmd = GET + "&field1=" + T + "&field2=" + H +"\r\n";
    Serial.print( "AT+CIPSEND=" );
    Serial.println( cmd.length() );
    if(Serial.find( ">" ) )
    {
        debug.print(">");
        debug.print(cmd);
        Serial.print(cmd);
    }
    else
    {
        sendDebug( "AT+CIPCLOSE" );
    }
    if( Serial.find("OK") )
    {
        debug.println( "RECEIVED: OK" );
    }
    else
    {
        debug.println( "RECEIVED: Error\nExit2" );
    }
}

void sendDebug(String cmd)
{
    debug.print("SEND: ");
    debug.println(cmd);
    Serial.println(cmd);
} 
 
boolean connectWiFi()
{
    Serial.println("AT+CWMODE=1");
    delay(2000);
    String cmd="AT+CWJAP=\"";
    cmd+=SSID;
    cmd+="\",\"";
    cmd+=PASS;
    cmd+="\"";
    sendDebug(cmd);
    delay(5000);
    if(Serial.find("OK"))
    {
        debug.println("RECEIVED: OK");
        return true;
    }
    else
    {
        debug.println("RECEIVED: Error");
        return false;
    }

    cmd = "AT+CIPMUX=0";
    sendDebug( cmd );
    if( Serial.find( "Error") )
    {
        debug.print( "RECEIVED: Error" );
        return false;
    }
}

整段程式中最重要的就是剛剛在 ThingSpeak 所得到的結果，還有就是無線網路名稱  (SSID) 與連線密碼 ( PASS )，這幾個重要的設定都在程式開頭 IoT Information 的地方。

不過除了SSID 和 PASS 修改為你的無線網路 AP 之外，其他的不需要做修改！

//*-- IoT Information
#define SSID "[無線網路熱點名稱]"
#define PASS "[無線網路連線密碼]"
#define IP "184.106.153.149" // ThingSpeak IP Address: 184.106.153.149
// 使用 GET 傳送資料的格式
// GET /update?key=[THINGSPEAK_KEY]&field1=[data 1]&filed2=[data 2]...;
String GET = "GET /update?key=[ThingSpeak_(Write)API_KEY]";

插上 Arduino 板子的線到電腦的 USB 插槽，設定好 Arduino IDE 板子類型 ( 和晶片類型 ) 和通訊埠號碼後，按下 upload 按鈕上傳此 Sketch 到 Arduino 板子上。

如果有裝上 USB 轉 TTL 模組，可以先將其插到 PC，再打開串列埠軟體等待 Arduino 通電之後輸出的數據。

開機之後得到的數據就如下面所示，遮蔽的部分是私有的資料，執行你自己的程式碼之後就會看到完整的輸出

訊息輸出

因為每隔 60 秒才會上傳一次，因此可以過一段時間再上去 ThingSpeak 看。下面是過了差不多20幾分鐘後的數據，我放在電腦的出風口並在旁邊開電風扇循環，不然溫度會變化不大！

ThingSpeak 環境溫濕度記錄圖

結論：

完成這個例子之後，應該對於程式碼裡面的ESP8266 AT 指令有點陌生！但是這不要緊，因為這就是一個實際例子，先知道 ESP8266 無線模組可以做些什麼，再來了解 AT 指令的操作會更容易了解！

ESP8266 無線模組，可當作一般串口轉無線模組使用，也可以利用它開放的 SDK 修改或是自己製作它的韌體，開發成一個具有無線網路功能的產品或是項目，相關的資料會持續地發佈在部落格上與大家做分享！

相信使用一段時間的 AT 指令之後，對於使用 Arduino IDE 與 AT 指令的配合或許不是那麼的滿意！那麼可以試試使用 ESP8266 Arduino AT 函式庫，相關的資料可以參考下面這三個網頁中的說明，與此篇網頁程式的加強版

• 自行更新 ESP8266  無線模組韌體至 - AT：1.2.0.0, SDK：1.5.4.1
• 給我一個可操作 AT 指令的 Arduino 函式庫 - 解決 AT 指令處理的蛋疼問題 (親測 AT v1.2.0.0 韌體)
• 初遇 IoT ( Internet of Thing, 物聯網 ) 加強版 - 使用 ESP8266 Arduino AT 函式庫上傳溫溼度資料到 Thingspeak ( AT v1.2.0.0 based on SDK 1.5.4.1)

*********************************************************************************
2017/01/03 更新：
因為很多問與答都是關於無法上傳資料到 Thingspeak 的問題，所以在這邊做個總結回覆，大抵上這個網頁中的問題就是這樣解決。

這個問題除了接線的問題之外，就是在程式執行之前必須確定在網址列手動輸入資料是可以正確成功的，再來就是修改程式碼需要的欄位，基本上就不會出現問題 ! 因為手動可以，程式碼就可以正確地將你的資料網上傳，所以只要出問題，就是檢查剛剛修改的欄位是否出現錯誤，因為這並不是程式出現問題，而是輸入參數設定錯誤造成上傳失敗。在相同的'網路環境之下，只是將手動變成自動而已，出現問題要先檢查這些部分 !

上述的問題都解決之後，另外會出現的問題可能就是上傳一段時間之後會失敗會是回傳 error 的問題。最近一位網友提問了這個問題，並且問到了重點，所以進行了幾封郵件的來回 (原文如附件(若連結失效，請回報)，文中遮蔽私人資料)，若有相同問題可看裡面的討論 ! 

 "給我一個可操作 AT 指令的 Arduino 函式庫 - 解決 AT 指令處理的蛋疼問題 (親測 AT v1.2.0.0 韌體)" 網頁中，對於程式範例也是採用這個方式解決亂碼或是通訊失敗的問題。
*********************************************************************************

---

<< 部落格相關文章 >>

• Google Spreadsheet（試算表）之 ESP8266 溫濕度紀錄與趨勢圖
• 當 ESP8266 遇上中華電信 IoT 智慧聯網大平台 { 入門 - 07 } - 結合 Arduino + ESP8266 實現 MQTT 主題訂閱與接收
• 當 ESP8266 遇上中華電信 IoT 智慧聯網大平台 { 入門 - 06 } -  了解 MQTT 協議，學習如何訂閱 MQTT 主題與接收 MQTT 發佈消息
• 當 ESP8266 遇上中華電信 IoT 智慧聯網大平台 { 入門 - 05 } - 結合 ESP8266 發佈 MQTT 消息
• 當 ESP8266 遇上中華電信 IoT 智慧聯網大平台 { 入門 - 04 } - 了解 MQTT 協議，學習如何發佈 MQTT 消息
• 當 ESP8266 遇上中華電信 IoT 智慧聯網大平台 { 入門 - 03 } - 使用 Arduino + ESP8266 上傳 SHT31 溫溼度數據
• 當 ESP8266 遇上中華電信 IoT 智慧聯網大平台 { 入門 - 02 } - 設備感測數據讀取與 (JSON) 解析
• 當 ESP8266 遇上中華電信 IoT 智慧聯網大平台 { 入門 - 01 } - 如何使用 ESP8266 利用 AT 指令取回中華電信 IoT 智慧聯網大平台上的設備感測器數據
• 如何使用 MCU 建立與其他 ESP8266 的 UDP 透傳通訊
• ESP8266 AT 指令下的透傳模式
• 如何使用 AT 指令讓同在 AP+STA 模式下的 ESP8266 互相通訊 ?
• 初遇 IoT ( Internet of Thing, 物聯網 ) 加強版 - 使用 ESP8266 Arduino AT 函式庫上傳溫溼度資料到 Thingspeak ( AT v1.2.0.0 based on SDK 1.5.4.1)
• 給我一個可操作 AT 指令的 Arduino 函式庫 - 解決 AT 指令處理的蛋疼問題 (親測 AT v1.2.0.0 韌體)
• 自行更新 ESP8266  無線模組韌體至 - AT：1.2.0.0, SDK：1.5.4.1
• ESP8266 ( ESP-01 ) 無線模組燒錄 NodeMCU 韌體 ( Lua 語法支援 )
• 自行更新 ESP8266 , ESP-01 無線模組韌體至 - AT：0.23, SDK：1.0.1
• 初遇 IoT ( Internet of Thing, 物聯網 ) - 使用 Arduino 控制 ESP8266 無線模組上傳資料到 IoT Server ( ThingSpeak )
• 操控 ESP8266 無線模組 - 經由 AP、STA 和 AP+STA 三種模式，學習 ESP8266 AT 指令
• 如何燒錄 ESP8266 無線模組的韌體 ( 使用一鍵燒錄軟體，燒錄版本：0018000902 )
• 初遇 IoT ( Internet of Thing, 物聯網 ) - 使用 Arduino 控制 ESP8266 無線模組上傳資料到 IoT Server ( ThingSpeak )
• 使用 Arduino IDE 開發 ESP8266 物聯網應用 - ThingSpeak, HTTP GET / POST 資料上傳方法
• 使用 Arduino IDE 開發 ESP8266 物聯網應用 - 取回 ThingSpeak 特定 Channel 和 Field 最後一筆資料
• ESP8266 入門學習套件支援 Arduino IDE 開發環境之安裝、使用說明與範例